Подключение нового отчета к подсистеме вариантов отчета

Здравствуйте.

Задача. Создать новый отчет и добавить его в подсистему вариантов отчета.

1. Чтобы добавить новый документ необходимо включить возможность редактирования нашей конфигурации.

Снять с поддержки конфигурацию

Редактирование с сохранением поддержки

2. Добавим новый отчет «БСП_НовыйОтчет». Например данный отчет будет показывать остатки по складам.

Новый отчет в конфигураторе

3. В модуль менеджера отчета добавим код.


Процедура НастроитьВариантыОтчета(Настройки, НастройкиОтчета) Экспорт
	НастройкиВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, НастройкиОтчета, "ОстаткиПоСкладам");
	НастройкиВарианта.Описание = НСтр("ru = 'Новый отчет по остаткам на складах.'");
КонецПроцедуры

Здесь «ОстаткиПоСкладам» — это ключ варианта отчета, определенного в настройках схемы компоновки данных
Ключ варианта отчета

4. Новый отчет необходимо добавить в какую-нибудь подсистему, по содержанию отчета наиболее подходит «Анализ запасов». Для этого необходимо разрешить редактирование данной подсистемы.
Подсистема анализ запасов

5. Отредактируем процедуру «НастроитьВариантыОтчетов» в общем модуле «ВариантыОтчетовПереопределяемый», добавим строку


ВариантыОтчетов.НастроитьОтчетВМодулеМенеджера(Настройки, Метаданные.Отчеты.БСП_НовыйОтчет);

Перед редактированием необходимо дать разрешение в настройках поддержки.
модуль ВариантыОтчетовПереопределяемый

6. Запускаем режим «1С:Предприятие» и с помощью обработки из набора внешних обработок библиотеки стандартных подсистем «ИнструментыРазработчикаОбновлениеВспомогательныхДанных.epf» обновляем наши новые данные. Перейдя к отчетам подсистемы «Склад и доставка» в подгруппе «Анализ запасов» будет и наш отчет.

Новый отчет в подсистеме вариантов отчетов

На этом можно и завершить.

Популярность: 2%

Рубрика: Настройка и оптимизация | Метки: | Добавить комментарий

Подключение нового объекта конфигурации к подсистеме внешних печатных форм

Здравствуйте.

Задача. Создать новый документ и добавить его в подсистему внешних печатных форм.

1. Чтобы добавить новый документ необходимо включить возможность редактирования нашей конфигурации.

Снять с поддержки конфигурацию

Редактирование с сохранением поддержки

2. Добавим новый документ с произвольной структурой

Новый документ

Также не забываем изменить описание и представление объекта.

3. В модуль менеджера документа добавить процедуры.


// Заполняет список команд печати.
// 
// Параметры:
//   КомандыПечати – ТаблицаЗначений – состав полей см. в функции УправлениеПечатью.СоздатьКоллекциюКомандПечати
//
Процедура ДобавитьКомандыПечати(КомандыПечати) Экспорт
	
КонецПроцедуры

// Формирует печатные формы.
//
// Параметры:
//  МассивОбъектов – Массив – ссылки на объекты, которые нужно распечатать;
//  ПараметрыПечати – Структура – дополнительные настройки печати;
//  КоллекцияПечатныхФорм – ТаблицаЗначений – сформированные табличные документы (выходной параметр)
//  ОбъектыПечати – СписокЗначений – значение – ссылка на объект;
//                                            представление – имя области, в которой был выведен объект (выходной параметр);
//  ПараметрыВывода – Структура – дополнительные параметры сформированных табличных документов (выходной параметр).
//
Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт
	
КонецПроцедуры

4. В форме списка в командную панель добавим группу кнопок с именем «Подменю печать».

Форма списка подменю печать

5. В модуле формы списка добавим процедуры.


&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	УправлениеПечатью.ПриСозданииНаСервере(ЭтотОбъект, Элементы.ПодменюПечать);
КонецПроцедуры

// СтандартныеПодсистемы.Печать
&НаКлиенте
Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)
    УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтотОбъект, Элементы.Список);
КонецПроцедуры
// Конец СтандартныеПодсистемы.Печать

6. В форме документа в командную панель добавим группу кнопок с именем «ПодменюПечать»

Форма документа подменю печать

7. В модуле формы документа добавим процедуры


&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	УправлениеПечатью.ПриСозданииНаСервере(ЭтотОбъект, Элементы.ПодменюПечать);
КонецПроцедуры
// СтандартныеПодсистемы.Печать
&НаКлиенте
Процедура Подключаемый_ВыполнитьКомандуПечати(Команда)
    УправлениеПечатьюКлиент.ВыполнитьПодключаемуюКомандуПечати(Команда, ЭтотОбъект, Объект);
КонецПроцедуры
// Конец СтандартныеПодсистемы.Печать

8. В общем модуле «УправлениеПечатьюПереопределяемый» отредактируем процедуру «ПриОпределенииОбъектовСКомандамиПечати» сначала предоставив возможность редактирования в настройках поддержки.

общий модуль УправлениеПечатьюПереопределяемый

В конце процедуры добавим строку


СписокОбъектов.Добавить(Документы.БСП_НовыйДокумент);

9. Запускаем режим «1С:Предприятие» и с помощью обработки из набора внешних обработок библиотеки стандартных подсистем «ИнструментыРазработчикаОбновлениеВспомогательныхДанных.epf» обновляем наши новые данные.

Обновление вспомогательных данных
10. Протестируем наши доработки. Добавим внешнюю печатную форму в подсистему «Печатные формы, отчеты и обработки»

Добавление обработки

Внешняя печатная форма
Откроем форму списка и выведем на экран команды печати

Команда внешней печатной формы

Результат печатной формы

На этом подключение нового объекта к подсистеме внешних печатных форм завершено.

Популярность: 1%

Рубрика: Настройка и оптимизация | Метки: | Добавить комментарий

Подключение нового объекта конфигурации к подсистеме запрета изменения данных

Здравствуйте.

Задача. Создать новый документ и добавить его в подсистему запрета изменения данных на определенную дату.

Решение данной задачи будем осуществлять на конфигурации «1С: Управление торговлей 11.2», но все действия можно применять и к другим конфигурациям, содержащим БСП (ЗУП 3, БУ 3, ERP 2 и т.д.).

1. Чтобы добавить новый документ необходимо включить возможность редактирования нашей конфигурации.

Снять с поддержки конфигурацию

Редактирование с сохранением поддержки

2. Добавим новый документ с произвольной структурой

Новый документ

Также не забываем изменить описание и представление объекта.

3. В форме документа добавим процедуру «ПриЧтенииНаСервере».


&НаСервере
Процедура ПриЧтенииНаСервере(ТекущийОбъект)
	ДатыЗапретаИзменения.ОбъектПриЧтенииНаСервере(ЭтотОбъект, ТекущийОбъект);
КонецПроцедуры

4. В общем модуле «ДатыЗапретаИзмененияПереопределяемый» необходимо доработать процедуру «ЗаполнитьИсточникиДанныхДляПроверкиЗапретаИзменения»


Процедура ЗаполнитьИсточникиДанныхДляПроверкиЗапретаИзменения(ИсточникиДанных) Экспорт
	ДатыЗапретаИзмененияУТ.ЗаполнитьИсточникиДанныхДляПроверкиЗапретаИзменения(ИсточникиДанных);
	ДатыЗапретаИзменения.ДобавитьСтроку(ИсточникиДанных, Метаданные.Документы.БСП_НовыйДокумент.ПолноеИмя(), "Дата"); //новая строка кода
КонецПроцедуры

Перед правкой модуля, необходимо разрешить его редактирование

ДатаЗапретаИзмененияПереопределяемый

5. Чтобы была проверка для записи нового документа или при удалении, необходимо создать 2 подписки на события:

  • «БСП_ПроверитьДатуЗапретаИзмененияПередЗаписьюДокумента» для события «ПередЗаписью», где источник наш документ «БСП_НовыйДокумент» и метод «ДатыЗапретаИзменения.ПроверитьДатуЗапретаИзмененияПередЗаписьюДокумента»

ПроверитьДатуЗапретаИзмененияПередЗаписьюДокумента

  • «БСП_ПроверитьДатуЗапретаИзмененияПередУдалениемДокумента» для события «ПередУдалением», где источник документ «БСП_НовыйДокумент» и метод «ДатыЗапретаИзменения.ПроверитьДатуЗапретаИзмененияПередУдалением»

ПроверитьДатуЗапретаИзмененияПередУдалениемДокумента

6. Запускаем режим «1С:Предприятие» и с помощью обработки из набора внешних обработок библиотеки стандартных подсистем «ИнструментыРазработчикаОбновлениеВспомогательныхДанных.epf» обновляем наши новые данные.

Обновление вспомогательных данных

На этом все, при установки даты запрета, данное ограничение будет распространяться на наш новый документ.

Популярность: 1%

Рубрика: Настройка и оптимизация | Метки: | Добавить комментарий

Подключение нового объекта конфигурации к подсистеме по работе с файлами

Здравствуйте.

В данной заметке я хочу рассказать как организовать работу с прикрепленными файлами для нового объекта в конфигурациях 1С, которые содержат библиотеку стандартных подсистем (БСП).

Задача. Создать новый документ и для этого документа добавить возможность прикреплять файлы.

Решение данной задачи будем осуществлять на конфигурации «1С: Управление торговлей 11.2», но все действия можно применять и к другим конфигурациям, содержащим БСП (ЗУП 3, БУ 3, ERP 2 и т.д.).

1. Чтобы добавить новый документ необходимо включить возможность редактирования нашей конфигурации.

Снять с поддержки конфигурацию

Редактирование с сохранением поддержки

2. Добавим новый документ с произвольной структурой

Новый документ

3. Добавим копированием новый справочник «БСП_НовыйДокументПрисоединенныеФайлы» и в реквизите «ВладелецФайла» изменим тип на «ДокументСсылка.БСП_НовыйДокумент». Для копирования был выбран справочник «ЗаказКлиентаПрисоединенныеФайлы».

Новый справочник присоединенных файлов

Также не забываем изменить описание и представление объекта.

4. Добавляем в определяемые типы «ВладелецПрисоединенныхФайлов», «ПрисоединенныйФайл», «ПрисоединенныйФайлОбъект» новые объекты.

ПрисоединенныйФайлОбъект

ПрисоединенныйФайлОбъект НовыйТип

ПрисоединенныйФайл

ПрисоединенныйФайл НовыйТип

ВладелецПрисоединенныхФайлов

ВладелецПрисоединенныхФайлов НовыйТип

5. Если необходимо добавить возможность копирования присоединенных файлов при копировании документа, то необходимо в параметры формы документа добавить параметр «ЗначениеКопирования» и сделать его ключевым.

Копирование присоединенных файлов

В модуль формы добавить процедуру «ПриЗаписиНаСервере».

 
&НаСервере
Процедура ПриЗаписиНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)
	ПрисоединенныеФайлы.ПриЗаписиНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи, Параметры);
КонецПроцедуры

6. Для отображения в форме списка наличия прикрепленных файлов необходимо доработать форму списка.

Изменим текст запроса списка

 
ВЫБРАТЬ
	ДокументБСП_НовыйДокумент.Ссылка,
	ДокументБСП_НовыйДокумент.ПометкаУдаления,
	ДокументБСП_НовыйДокумент.Номер,
	ДокументБСП_НовыйДокумент.Дата,
	ДокументБСП_НовыйДокумент.Проведен,
	ДокументБСП_НовыйДокумент.Реквизит1,
	ДокументБСП_НовыйДокумент.Реквизит2,
	ДокументБСП_НовыйДокумент.МоментВремени,
	ВЫБОР
		КОГДА НаличиеПрисоединенныхФайлов.ЕстьФайлы ЕСТЬ NULL 
			ТОГДА 1
		КОГДА НаличиеПрисоединенныхФайлов.ЕстьФайлы
			ТОГДА 0
		ИНАЧЕ 1
	КОНЕЦ КАК ЕстьФайлы
ИЗ
	Документ.БСП_НовыйДокумент КАК ДокументБСП_НовыйДокумент
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.НаличиеПрисоединенныхФайлов КАК НаличиеПрисоединенныхФайлов
		ПО ДокументБСП_НовыйДокумент.Ссылка = НаличиеПрисоединенныхФайлов.ОбъектСФайлами

В форму списка добавим колонку «ЕстьФайлы» и изменим настройки отображения.

Наличие прикрепленных файлов

7. Тестирование.

Запускаем режим «1С:Предприятие» и с помощью обработки из набора внешних обработок библиотеки стандартных подсистем «ИнструментыРазработчикаОбновлениеВспомогательныхДанных.epf» обновляем наши новые данные.

Обновление вспомогательных данных

Список документов
Список документов с прикрепленными файлами

Форма документа
Кнопка "Файлы"

Прикрепленный файл
Прикрепленный файл документа

Популярность: 2%

Рубрика: Настройка и оптимизация | Метки: | 3 комментария

Подключение нового объекта конфигурации к подсистеме дополнительных отчетов и обработок

Здравствуйте.

В данной заметке будет описан алгоритм действий подключения нового объекта (например документа) в типовой конфигурации 1С к подсистеме «Дополнительные отчеты и обработки».

Пример будет рассмотрен на конфигурации «1С: Управление торговлей 11.2», но все действия, рассмотренные в статье, можно применять и к другим конфигурациям (ЗУП 3, БУ 3, ERP 2 и т.д.).

1. Чтобы добавить новый документ необходимо включить возможность редактирования нашей конфигурации.

Снять с поддержки конфигурацию

Редактирование с сохранением поддержки

2. Добавим новый документ с произвольной структурой

Новый документ

3. В формы документа (списка и объекта) необходимо добавить следующий код (не забываем при этом для форм определить процедуру «ПриСозданииНаСервере»)


&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	ДополнительныеОтчетыИОбработки.ПриСозданииНаСервере(ЭтотОбъект);
КонецПроцедуры

#Область ОбработчикиКомандФормы
// СтандартныеПодсистемы.ДополнительныеОтчетыИОбработки
&НаКлиенте
Процедура Подключаемый_ВыполнитьНазначаемуюКоманду(Команда)
    Если Не ДополнительныеОтчетыИОбработкиКлиент.ВыполнитьНазначаемуюКомандуНаКлиенте(ЭтотОбъект, Команда.Имя) Тогда
        ДополнительныеОтчетыИОбработкиВыполнитьНазначаемуюКомандуНаСервере(Команда.Имя);
    КонецЕсли;
КонецПроцедуры
// Конец СтандартныеПодсистемы.ДополнительныеОтчетыИОбработки
#КонецОбласти

#Область СлужебныеПроцедурыИФункции
// СтандартныеПодсистемы.ДополнительныеОтчетыИОбработки
&НаСервере
Процедура ДополнительныеОтчетыИОбработкиВыполнитьНазначаемуюКомандуНаСервере(ИмяЭлемента)
    ДополнительныеОтчетыИОбработки.ВыполнитьНазначаемуюКомандуНаСервере(ЭтотОбъект, ИмяЭлемента);
КонецПроцедуры
// Конец СтандартныеПодсистемы.ДополнительныеОтчетыИОбработки
#КонецОбласти

ПриСозданииНаСервере

4. Для определяемого типа «ОбъектСДополнительнымиКомандами» необходимо добавить наш новый документ, но для этого надо сначала дать возможность его редактировать.

ОбъектСДополнительнымиКомандами

ОбъектСДополнительнымиКомандами

На этом работы в конфигураторе завершены.

5. Запускаем режим «1С:Предприятие» и с помощью обработки из набора внешних обработок библиотеки стандартных подсистем «ИнструментыРазработчикаОбновлениеВспомогательныхДанных.epf» обновляем наши новые данные.

Обновление вспомогательных данных

Чтобы проверить результат, добавим внешнюю обработку по заполнению.

Добавление обработки

Добавление обработки

После успешного добавления, проверим результат в формах документа.

Форма списка
Внешняя обработка в форме списка

Форма документа
Внешняя обработка в форме документа

На этом все, как видите ничего сложного.

Популярность: 2%

Рубрика: Настройка и оптимизация | Метки: | Добавить комментарий